How To Accept Drag And Drop Files Onto A ListView

You may in need of dragging and dropping files from explorer onto a listview (or another control) on a form. Here’s a simple way to deal with that.

First, we know that each Delphi control has message handler procedure known as Window Proc, for handling messages from Windows.

A ListView has this procedure of course. To implement drag and drop on a ListView, we must override the window proc of the ListView with our customized window proc, and implement code of our needs there.

The steps are:

1. Save old ListView’s window proc
2. Create a new window proc for the ListView and our codes there
3. Filter messages from Windows. If our new window proc receives message that match our need, then process it else pass it to old saved window proc
4. Enable the ListView to accept files

To have those all done, we need to to add ShellApi to uses list.

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, ComCtrls, ShellApi;

Then we define two procedures to handle messages, and a variable to save old window proc:

type
TForm3 = class(TForm)
ListView1: TListView;
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
OldLvWndProc : TWndMethod;
procedure OnDropFiles(var msg: TWMDropFiles);
procedure LvWndProc(var Msg: TMessage);
public
{ Public declarations }
end;

Now the code for the new window proc to filter messages (we need only WM_DROPFILES):

procedure TForm3.LvWndProc(var Msg: TMessage);
begin
if msg.Msg = WM_DROPFILES then
OnDropFiles(TWMDropFiles(msg))
else
OldLvWndProc(msg);
end;

And the code for handling files dropped on the ListView:

procedure TForm3.OnDropFiles(var msg: TWMDropFiles);
var
FCount, i: Integer;
FName: array [0..MAX_PATH] of char;
begin
ListView1.Items.BeginUpdate;
ListView1.Items.Clear;
try
{How many files droppped?}
FCount := DragQueryFile(msg.Drop, $FFFFFFFF, FName, MAX_PATH);
for i:= 0 to FCount-1 do
begin
{Add them to the ListView}
DragQueryFile(msg.Drop, i, FName, MAX_PATH);
with ListView1.Items.Add do
begin
Caption := STring(FName);
{Is current file a folder or a file?}
if DirectoryExists(string(FName)) then
SubItems.Add('Directory')
else
SubItems.Add('File');
end;
end;
finally
ListView1.Items.EndUpdate;
end;
end;

The last, we enable the ListView to accept files and replace window proc with the new one:

procedure TForm3.FormCreate(Sender: TObject);
begin
OldLvWndProc         := ListView1.WindowProc;
ListView1.WindowProc := LvWndProc;
DragAcceptFiles(ListView1.Handle, True);
end;

And here’s the whole code:

unit Unit3;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, ComCtrls, ShellApi;

type
TForm3 = class(TForm)
ListView1: TListView;
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
OldLvWndProc : TWndMethod;
procedure OnDropFiles(var msg: TWMDropFiles);
procedure LvWndProc(var Msg: TMessage);
public
{ Public declarations }
end;

var
Form3: TForm3;

implementation

{$R *.dfm}

{ TForm3 }

procedure TForm3.FormCreate(Sender: TObject);
begin
OldLvWndProc         := ListView1.WindowProc;
ListView1.WindowProc := LvWndProc;
DragAcceptFiles(ListView1.Handle, True);
end;

procedure TForm3.LvWndProc(var Msg: TMessage);
begin
if msg.Msg = WM_DROPFILES then
OnDropFiles(TWMDropFiles(msg))
else
OldLvWndProc(msg);
end;

procedure TForm3.OnDropFiles(var msg: TWMDropFiles);
var
FCount, i: Integer;
FName: array [0..MAX_PATH] of char;
begin
ListView1.Items.BeginUpdate;
ListView1.Items.Clear;
try
{How many files droppped?}
FCount := DragQueryFile(msg.Drop, $FFFFFFFF, FName, MAX_PATH);
for i:= 0 to FCount-1 do
begin
{Add them to the ListView}
DragQueryFile(msg.Drop, i, FName, MAX_PATH);
with ListView1.Items.Add do
begin
Caption := STring(FName);
{Is current file a folder or a file?}
if DirectoryExists(string(FName)) then
SubItems.Add('Directory')
else
SubItems.Add('File');
end;
end;
finally
ListView1.Items.EndUpdate;
end;
end;

end.

Hope this post helps someone who in need. Leave comment if you have any question

Download The Source

The source code of this post (sample app.):

Drag And Drop Files Onto A ListView (248.4 KiB)

Related Topic

Tutorial Instalasi Komponen TPicShowMembuat Smooth Slideshow Dengan DelphiContoh Penggunaan WM_NCHITTEST Di DelphiTipe PointerTES BLOGPLANET

Incoming search terms:

• contoh aplikasi delphi dengan cxgrid
• winapi drop file in control
• contoh script yg menggunakan shellapi
• clistview Accept files
• wallpaper asian girl
• ondropfiles
• how to handle drag drop link on lazarus component
• how to drag and drop onto a windows form
• drag and drop explorer listview
• delphi listview file drop

Comments

comments

Powered by Facebook Comments